ELM327とArduinoとLCD2004でOBDデータ表示

void setup() {
  // put your setup code here, to run once:
  pinMode(0,INPUT);
  pinMode(1,INPUT);
  digitalWrite(0,HIGH);
  digitalWrite(1,HIGH);
}

void loop() {
  // put your main code here, to run repeatedly:

}

/*
Arduino Pro mini : 16bit
システムのクロック : 16MHz
電源電圧 ： 5V

LCD
2004 20桁4行
I2C接続
SDA - A4
SCL - A5

ELM327との接続
ソフトウェアシリアル
RX pin2
TX pin3
*/

#include <SoftwareSerial.h>
#include <Wire.h>

#define lcdaddr 0x27 // スレーブアドレス0x27
#define lcdEN 0b00000100 // Enable
#define lcdBL 0b00001000 // Back light ON
#define setDDRAMaddr 0b10000000 // Set DDRAM Address
#define setRS 0b00000001 // RS=1
#define unsetRS 0b00000000 // RS=0

#define val1 20 // 配列の大きさ
#define aveval 8 // 平均を取る数

bool state = false; // Builtin LEDのステータス用
bool flg0 = false;
bool flg1 = false;
bool flg2 = false;

const byte rxPin = 2;
const byte txPin = 3;

SoftwareSerial mySerial (rxPin, txPin);

char receivevalue[val1] = {0}; // 受信文字数に応じて配列の大きさを調整 複数PIDなら大きく調整必要
int i0 = 0;
int n = 0;
unsigned char cnt0 = 0;
unsigned char cnt1 = 0;
unsigned char cnt2 = 0;
int valcon0 = 0;
int valcon1 = 0;
int coolant = 0;
int intake = 0;
unsigned int runtimesince = 0; // 16bitのため、unsigned int(～65535)としないとオーバーフローする
float modulevoltage = 0.0;
float throttle = 0.0;
unsigned int A = 0;
unsigned int B = 0;
char buf[6]; // Run time since engine startの最大値が65,535で5桁 Null終点文字が自動的に付加のため+1
unsigned long t0; // 時間計測用
unsigned int vspeed[aveval] = {0}; // 車速 平均化用の配列
unsigned char cnt3 = 0;
unsigned int vspeedsum = 0;
unsigned int vspeedave = 0;
unsigned int erpm[aveval] = {0}; // エンジン回転数 平均化用の配列
unsigned char cnt4 = 0;
unsigned int erpmsum = 0;
unsigned int erpmave = 0;

// 0105 : Engine coolant temperature A - 40
// 010c : Engine speed (256 * A + B) / 4
// 010d : Vehicle speed 	A
// 010f : Intake air temperature 	A - 40
// 0111 : Throttle position (100 / 255) * A
// 011f : Run time since engine start 256 * A + B
// 0142 : Control module voltage (256 * A + B) / 1000

// 取得頻度毎にPIDを分ける
char* PIDS0[]={"010c","010d","0142","0111"};
char* PIDS1[]={"011f"};
char* PIDS2[]={"0105","010f"};

int asciiTOhex(char c_high,char c_low){
  int i = String(c_high,HEX).toInt();
  int j = String(c_low,HEX).toInt();
  // ascii character to character code(hex)
  if(i < 41){ // ascii A 0x41 A~ より前 ＝ 数値
    i = i - 30;
  }
  else{
    i = i - 31;
  }
  // hex to dec
  i = i << 4; // 2^4=16 乗算
  if(j < 41){
    j = j - 30;
  }
  else{
    j = j - 31;
  }
  int k = i + j;
  return k;
}

int asciiTOint(char c){
  int i = String(c,HEX).toInt(); // ascii character to character code(hex)
  return i;
}

void lcdinit()
{
  // 一旦8bitモードに設定（3回繰り返す）
  // 1回目
  lcdwrite0(0x30,unsetRS); // Funcition Set DL=1:8bitバス
  delay(5); // Wait for more than 4.1 ms

  // 2回目
  lcdwrite0(0x30,unsetRS);
  delayMicroseconds(150); // Wait for more than 100 µs

  // 3回目
  lcdwrite0(0x30,unsetRS);
  delayMicroseconds(100); // Wait for more than 40 µs

  lcdwrite0(0x20,unsetRS); // 4bitモードに設定 Funcition Set DL=0:4bitバス
  lcdwrite(0x28,unsetRS); // 2行表示モードに設定 Funcition Set DL=0:4bitバス,Set N=1:2桁表示
  lcdwrite(0x0F,unsetRS); // 表示ON/OFF D=1:文字表示ON,C=1:下線カーソルON,B=1:ブロックカーソルON
  lcdwrite(0x06,unsetRS); // エントリモードセット I/D=1:インクリメント
  lcdwrite(0x01,unsetRS); // 表示クリア
  lcdwrite(0x02,unsetRS); // カーソルホーム
}

// 8bit用
void lcdwrite0(byte bits,byte mode){
  i2cwrite(bits | mode);
}

// 4bit用
void lcdwrite(byte bits,byte mode){
  i2cwrite((bits & 0xF0) | mode); // 上位4bit
  i2cwrite(((bits << 4) & 0xF0) | mode); // 下位4bit
}

void i2cwrite(byte val){
  Wire.beginTransmission(lcdaddr);
  Wire.write(val | lcdBL);
  delayMicroseconds(1); // 0.22us以上
  Wire.write(val | lcdBL | lcdEN);
  delayMicroseconds(1); // 0.22us以上
  Wire.write(val | lcdBL);
  Wire.endTransmission();
  delayMicroseconds(100); // Wait for more than 40 µs とは言いつつ50usec待ちでは動かない 100usecぐらい余裕を持っておく
}

// row:行 col:列
void setCursor(int row, int col){
  int row_offsets[] = {0x00, 0x40, 0x14, 0x54}; // 0から数え始め
  lcdwrite((col + row_offsets[row]) | setDDRAMaddr,unsetRS);
}

void lcdText(String s){
  for(int i = 0; i < s.length(); i++){
    lcdwrite(s.charAt(i),setRS);
  }
}

void setup() {
  delay(50); // Wait for more than 15 ms after VCC rises to 4.5 V
  pinMode(LED_BUILTIN,OUTPUT);
  pinMode(rxPin, INPUT); // Define pin modes for TX and RX
  pinMode(txPin, OUTPUT); // Define pin modes for TX and RX
  mySerial.begin(38400);
  Serial.begin(38400);
  Serial.println("Connect to PC serial port");
  Wire.begin();
  lcdinit();

  // LCD表示。単位など、固定表示
  setCursor(0,6);
  lcdText("ECT");

  setCursor(1,6);
  lcdText("IAT");

  setCursor(1,16);
  lcdText("%");

  setCursor(2,6);
  lcdText("km/h");

  setCursor(2,16);
  lcdText("RPM");

  setCursor(3,6);
  lcdText("V");

  setCursor(3,16);
  lcdText("s");

  t0 = millis(); // 初期時刻
}

void loop() {

  // データ取得（送受信）
  if(flg0 == true || flg1 == true || flg2 == true){

    if(flg0 == true){
      // PIDS0 リクエスト 送信
      mySerial.println(PIDS0[n]);
    }
    else if(flg1 == true){
      mySerial.println(PIDS1[n]);
    }
    else if(flg2 == true){
      mySerial.println(PIDS2[n]);
    }
    else{}
    mySerial.print("\r");

    // データ受信
    while(mySerial.available()>0){
      receivevalue[i0] = mySerial.read();
      i0++;
    }

    valcon0 = asciiTOint(receivevalue[3]); // 受信PID
    valcon1 = asciiTOint(receivevalue[4]); // 受信PID
    A = asciiTOhex(receivevalue[6],receivevalue[7]); // データバイトの1バイト目
    B = asciiTOhex(receivevalue[9],receivevalue[10]); // データバイトの2バイト目

    if(valcon0 == 30){ //0=0x30
      if(valcon1 == 35){ // 5=0x35 0105 Engine coolant temperature A - 40
        coolant = A - 40;
      }
      else if(valcon1 == 43){ // C=0x43
        erpm[cnt4] = ((A<<8)+B)>>2;
        cnt4++;
        for(int i=0;i<aveval;i++){
          erpmsum += erpm[i];
          erpmave = erpmsum >> 3; // 8分の1
        }
        erpmsum = 0;
        if(cnt4 >= aveval){
          cnt4 = 0;
        }
      }
      else if(valcon1 == 44 ){ // D=0x44
        vspeed[cnt3] = A;
        cnt3++;
        for(int i=0;i<aveval;i++){
          vspeedsum += vspeed[i];
          vspeedave = vspeedsum >> 3; // 8分の1
        }
        vspeedsum = 0;
        if(cnt3 >= aveval){
          cnt3 = 0;
        }
      }
      else if(valcon1 == 46 ){ // F=0x46
        intake = A - 40;
      }
      else{}
    }
    else if(valcon0 == 31){ // 1=0x31
      if(valcon1 == 31){ // 1=0x31
        throttle = A*100; // 後ほど255でわる
      }
      if(valcon1 == 46){ // F=0x46
        runtimesince = (A<<8)+B;
      }
      else{}
    }
    else if(valcon0 = 34){ // 4=0x34
      if(valcon1 == 32){ // 2=0x32
        modulevoltage = (A<<8)+B; // 後ほど1000で割る ex)14277V → 14.277V

        // 受信する値の例
        // txData[3] = 0x37; // A dec 55
        // txData[4] = 0xC5; // B dec 197
        // (A * 256 + B)/1000
        // (55 * 256 + 197)/1000 = 14.277V

      }
      else{}
    }
    else{}

    delay(5); // 少し待たないと正しく送受信が完了しない
    i0 = 0;
    n++;

    if(flg0 == true){
      if(n >= (sizeof(PIDS0)>>1)){ // pid送受信終わり pid数に合わせる
        n = 0;
        flg0 = false;
      }
    }
    else if(flg1 == true){
      if(n >= (sizeof(PIDS1)>>1)){ // pid送受信終わり pid数に合わせる
        n = 0;
        flg1 = false;
      }
    }
    else if(flg2 == true){
      if(n >= (sizeof(PIDS2)>>1)){ // pid送受信終わり pid数に合わせる
        n = 0;
        flg2 = false;
      }
    }
    else{}

    // LCD表示部
    sprintf(buf,"%3d",coolant);
    setCursor(0,1);
    lcdText(buf);
    
    sprintf(buf,"%3d",intake);
    setCursor(1,1);
    lcdText(buf);

    dtostrf(throttle/255,4,1,buf);
    setCursor(1,11);
    lcdText(buf);
    
    sprintf(buf,"%3d",vspeedave);
    setCursor(2,1);
    lcdText(buf);
    
    sprintf(buf,"%4d",erpmave);
    setCursor(2,11);
    lcdText(buf);
    
    dtostrf(modulevoltage/1000,4,1,buf);
    setCursor(3,1);
    lcdText(buf);

    sprintf(buf,"%5d",runtimesince);
    setCursor(3,10);
    lcdText(buf);
  }

  unsigned long t1 = millis();

  if((t1-t0) > 100){ // 100ms計測
    // 動作確認用LED
    if(state){
      digitalWrite(LED_BUILTIN,LOW);
    }
    else{
      digitalWrite(LED_BUILTIN,HIGH);
    }
    state = !state;

    cnt0++;
    cnt1++;
    cnt2++;

    t0 = t1;
  }

  // lcd表示値の更新
  // lcd表示を
  // 400ms毎 早く更新したいもの
  if(cnt0 > 4){
    cnt0 = 0;
    flg0 = true;
  }
  // 1sec毎 runtimesinceの単位はsec
  if(cnt1 > 10){
    cnt1 = 0;
    flg1 = true;
  }
  // 5sec毎 温度関係
  if(cnt2 > 50){
    cnt2 = 0;
    flg2 = true;
  }
}